Dx02.f90 のサンプルプログラム


!*********************************************************************
!  Dx02.f90    use DirectX9 with gfortran.
!              2017.08.03 Y.Akatsuka
!              2025.05.13 Y.Akatsuka
!*********************************************************************
! Define constants & structures
module win32_types
   use ISO_C_BINDING
   implicit NONE
    integer, parameter :: CS_VREDRAW   =  INT(Z'00000001')
    integer, parameter :: CS_HREDRAW   =  INT(Z'00000002')
    integer, parameter :: CW_USEDEFAULT = INT(Z'80000000')
    integer, parameter :: SW_SHOWNORMAL = 1
    integer, parameter :: WM_CREATE    =  INT(Z'00000001')
    integer, parameter :: WM_DESTROY   =  INT(Z'00000002')
    integer, parameter :: WM_PAINT     =  INT(Z'0000000F')
    integer, parameter :: WM_CLOSE     =  INT(Z'00000010')
    integer, parameter :: WM_QUIT      =  INT(Z'00000012')
    integer, parameter :: WM_KEYDOWN   =  INT(Z'00000100')
    integer, parameter :: WM_COMMAND   =  INT(Z'00000111')
    integer, parameter :: VK_RIGHT     =  INT(Z'00000027')
    integer, parameter :: VK_LEFT      =  INT(Z'00000025')
    integer, parameter :: VK_UP        =  INT(Z'00000026')
    integer, parameter :: VK_DOWN      =  INT(Z'00000028')
    integer, parameter :: IDC_ARROW    =  INT(Z'00007F00')
    integer, parameter :: IDI_APPLICATION=INT(Z'00007F00')
    integer, parameter :: COLOR_WINDOW =  5
    integer, parameter :: HANDLE       =  4
    integer, parameter :: WHITE_BRUSH  =  0
    integer, parameter :: BLACK_BRUSH  =  4
    integer, parameter :: WS_OVERLAPPEDWINDOW = INT(Z'00CF0000')
    integer, parameter :: DT_LEFT      =  0
    integer, parameter :: PM_REMOVE    =  1
!
   type, bind(C) :: WNDCLASSEX_T
      integer(C_INT)      cbSize
      integer(C_INT)      style
      type(C_FUNPTR)      lpfnWndProc
      integer(C_INT)      cbClsExtra
      integer(C_INT)      cbWndExtra
      integer(C_INTPTR_T) hInstance
      integer(C_INTPTR_T) hIcon
      integer(C_INTPTR_T) hCursor
      integer(C_INTPTR_T) hbrBackground
      type(C_PTR)         lpszMenuName
      type(C_PTR)         lpszClassName
      integer(C_INTPTR_T) hIconSm
   end type WNDCLASSEX_T
!
   type, bind(C) :: POINT_T
      integer(C_LONG) x
      integer(C_LONG) y
   end type POINT_T
!
   type, bind(C) :: MSG_T
      integer(C_INTPTR_T) hwnd
      integer(C_INT)      message
      integer(C_INTPTR_T) wParam
      integer(C_INTPTR_T) lParam
      integer(C_LONG)     time
      type(POINT_T)       pt
   end type MSG_T
!
   type, bind(C) :: RECT_T
      integer(C_LONG) left
      integer(C_LONG) top
      integer(C_LONG) right
      integer(C_LONG) bottom
   end type RECT_T
!
   type, bind(C) :: PAINTSTRUCT_T
      integer(C_INTPTR_T) hdc
      integer(C_INT)      fErase
      type(RECT_T)        rcPaint
      integer(C_INT)      fRestore
      integer(C_INT)      fIncUpdate
      integer(C_INT8_T)   rgbReserved(32)
   end type PAINTSTRUCT_T
!
end module win32_types
!
! *******************************************************************
!     Define function interfaces.
! *******************************************************************
module win32
   implicit none
   interface
!
   function DefWindowProc(hwnd, Msg, wParam, lParam) &
            bind(C,name='DefWindowProcA')
   use ISO_C_BINDING
!GCC$ ATTRIBUTES STDCALL :: DefWindowProc
   integer(C_INT) DefWindowProc
   integer(C_INTPTR_T), value :: hwnd,wParam,lParam
   integer(C_INT), value :: Msg
   end function DefWindowProc
!
   function LoadIcon(hInstance,lpIconName) bind(C,name='LoadIconA')
   use ISO_C_BINDING
!GCC$ ATTRIBUTES STDCALL :: LoadIcon
   integer(C_INTPTR_T) LoadIcon
   integer(C_INTPTR_T), value :: hInstance
!  character(kind=C_CHAR) lpIconName(*)
   integer(C_INT), value :: lpIconName      ! alternate parameter
   end function LoadIcon
!
   function LoadCursor(hInstance,lpCursorName) bind(C,name='LoadCursorA')
   use ISO_C_BINDING
!GCC$ ATTRIBUTES STDCALL :: LoadCursor
   integer(C_INTPTR_T)  LoadCursor
   integer(C_INTPTR_T), value :: hInstance
!  character(kind=C_CHAR) lpCursorName(*)
   integer(C_INT), value :: lpCursorName    ! alternate parameter
   end function LoadCursor
!
   function CreateWindowEx(dwExStyle,lpClassName,lpWindowName,&
            dwStyle,x,y,nWidth,nHeight,hWndParent,hMenu, &
            hInstance,lpParam) bind(C,name='CreateWindowExA')
   use ISO_C_BINDING
!GCC$ ATTRIBUTES STDCALL :: CreateWindowEx
   integer(C_INTPTR_T) CreateWindowEx
   integer(C_LONG), value :: dwExStyle
   character(kind=C_CHAR) :: lpClassName(*)
   character(kind=C_CHAR) :: lpWindowName(*)
   integer(C_LONG), value :: dwStyle
   integer(C_INT), value  :: x,y,nWidth,nHeight
   integer(C_INTPTR_T), value  :: hWndParent,hMenu,hInstance
   type(C_PTR), value :: lpParam
   end function CreateWindowEx
!
   function ShowWindow(hWnd,nCmdShow) bind(C,name='ShowWindow')
   use ISO_C_BINDING
!GCC$ ATTRIBUTES STDCALL :: ShowWindow
   integer(C_INT) ShowWindow
   integer(C_INTPTR_T), value :: hWnd
   integer(C_INT), value :: nCmdShow
   end function ShowWindow
!
   logical function UpdateWindow(hWnd) bind(C,name='UpdateWindow')
   use ISO_C_BINDING
!GCC$ ATTRIBUTES STDCALL :: UpdateWindow
   integer(C_INTPTR_T), value :: hWnd
   end function UpdateWindow
!
   function RegisterClassEx(WndClass) bind(C,name='RegisterClassExA')
   use ISO_C_BINDING
   use win32_types
!GCC$ ATTRIBUTES STDCALL :: RegisterClassEx
   integer(C_SHORT) RegisterClassEx
   type(WNDCLASSEX_T) WndClass
   end function RegisterClassEx
!
   function GetStockObject(fnObject) bind(C,name='GetStockObject')
   use ISO_C_BINDING
!GCC$ ATTRIBUTES STDCALL :: GetStockObject
   integer(C_INTPTR_T) GetStockObject
   integer(C_INT), value :: fnObject
   end function GetStockObject
!
   logical function GetMessage(lpMsg,hWnd,wMsgFilterMin,wMsgFilterMax) &
   bind(C,name='GetMessageA')
   use ISO_C_BINDING
   use win32_types
!GCC$ ATTRIBUTES STDCALL :: GetMessage
   type(MSG_T) lpMsg
   integer(C_INTPTR_T), value :: hWnd
   integer(C_INT), value :: wMsgFilterMin,wMsgFilterMax
   end function GetMessage
!
   function TranslateMessage(lpMsg) bind(C,name='TranslateMessage')
   use ISO_C_BINDING
   use win32_types
!GCC$ ATTRIBUTES STDCALL :: TranslateMessage
   integer(C_INT) TranslateMessage
   type(MSG_T) lpMsg
   end function TranslateMessage
!
   function DispatchMessage(lpMsg) bind(C,name='DispatchMessageA')
   use ISO_C_BINDING
   use win32_types
!GCC$ ATTRIBUTES STDCALL :: DispatchMessage
   integer(C_LONG) DispatchMessage
   type(MSG_T) lpMsg
   end function DispatchMessage
!
   subroutine PostQuitMessage(nExitCode) bind(C,name='PostQuitMessage')
   use ISO_C_BINDING, only: C_INT
!GCC$ ATTRIBUTES STDCALL :: PostQuitMessage
   integer(C_INT), value :: nExitCode
   end subroutine PostQuitMessage
!
   function BeginPaint(hwnd,lpPaint) bind(C,name='BeginPaint')
   use win32_types
!GCC$ ATTRIBUTES STDCALL :: BeginPaint
   integer(C_INTPTR_T) BeginPaint
   integer(C_INTPTR_T), value :: hwnd
   type(PAINTSTRUCT_T) lpPaint
   end function BeginPaint
!
   function EndPaint(hwnd,lpPaint) bind(C,name='EndPaint')
   use win32_types
!GCC$ ATTRIBUTES STDCALL :: EndPaint
   integer(C_INT) EndPaint
   integer(C_INTPTR_T), value :: hwnd
   type(PAINTSTRUCT_T) lpPaint
   end function EndPaint
!
   logical function GetClientRect(hwnd,lpRect) bind(C,name='GetClientRect')
   use win32_types
!GCC$ ATTRIBUTES STDCALL :: GetClientRect
   integer(C_INT) GetClientRect
   integer(C_INTPTR_T), value :: hwnd
   type(RECT_T) lpRect
   end function GetClientRect
!
   function DrawTextEx(hdc,lpchText,cchText,lprc,dvDTFormat,lpDTParams) &
            bind(C,name='DrawTextExA')
   use win32_types
!GCC$ ATTRIBUTES STDCALL :: DrawTextEx
   integer(C_INT) DrawTextEx
   integer(C_INTPTR_T), value :: hdc
   character(kind=C_CHAR) :: lpchText(*)
   integer(C_INT), value :: cchText  ! -1 to calculate the length
   type(RECT_T) lprc
   integer(C_INT), value :: dvDTFormat
   integer(C_INTPTR_T), value :: lpDTParams
   end function DrawTextEx
!
   logical function TextOut(hdc,nXstart,nYstart,lpString,cbString)  &
            bind(C,name='TextOutA')
   use ISO_C_BINDING
!GCC$ ATTRIBUTES STDCALL :: TextOut
   integer(C_INTPTR_T), value :: hdc
   integer(C_INT), value :: nXstart,nYstart,cbString
   character(kind=C_CHAR) :: lpString(*)
   end function TextOut
!
   function SetTextColor(hdc,crColor) bind(C,name='SetTextColor')
   use ISO_C_BINDING
!GCC$ ATTRIBUTES STDCALL :: SetTextColor
   integer(C_INT) SetTextColor
   integer(C_INTPTR_T), value :: hdc
   integer(C_INT), value :: crColor
   end function SetTextColor
!
   function SetBkMode(hdc,iBkMode) bind(C,name='SetBkMode')
   use ISO_C_BINDING
!GCC$ ATTRIBUTES STDCALL :: SetBkMode
   integer(C_INT) SetBkMode
   integer(C_INTPTR_T), value :: hdc
   integer(C_INT), value :: iBkMode
   end function SetBkMode
!
   function MessageBox(hWnd,lpText,lpCaption,uType) bind(C,name='MessageBoxA')
   use ISO_C_BINDING
!GCC$ ATTRIBUTES STDCALL :: MessageBox
   integer(C_INT) MessageBox
   integer(C_INTPTR_T), value :: hWnd
   integer(C_INT), value :: uType
   character(kind=C_CHAR) :: lpText(*),lpCaption(*)
   end function MessageBox
!
   function SendMessage(hWnd,Msg,wParam,lParam) bind(C,name='SendMessageA')
   use ISO_C_BINDING
!GCC$ ATTRIBUTES STDCALL :: SendMessage
   integer(C_INT) SendMessage
   integer(C_INTPTR_T), value :: hWnd,wParam,lParam
   integer(C_INT), value :: Msg
   end function SendMessage
!
   function DestroyWindow(hWnd) bind(C,name='DestroyWindow')
   use ISO_C_BINDING
!GCC$ ATTRIBUTES STDCALL :: DestroyWindow
   integer(C_INT) DestroyWindow
   integer(C_INTPTR_T), value :: hWnd
   end function
!
   function ClientToScreen(hWnd,lpPoint) bind(C,name='ClientToScreen')
   use win32_types
!GCC$ ATTRIBUTES STDCALL :: ClientToScreen
   integer(C_INT) ClientToScreen
   integer(C_INTPTR_T), value :: hWnd
   type(POINT_T) lpPoint
   end function
!
   subroutine ZeroMemory(Dest,Length) bind(C,name='RtlZeroMemory')
   use ISO_C_BINDING
!GCC$ ATTRIBUTES STDCALL :: ZeroMemory
   integer(C_INTPTR_T), value :: Dest
   integer(C_INTPTR_T), value :: Length
   end subroutine ZeroMemory

   subroutine MoveMemory(Dest,Source,Length) bind(C,name='RtlMoveMemory')
   use ISO_C_BINDING
!GCC$ ATTRIBUTES STDCALL :: MoveMemory
   integer(C_INTPTR_T), value :: Dest,Source
   integer(C_INTPTR_T), value :: Length
   end subroutine MoveMemory

   end interface
end module win32

!*********************************************************************
!  Define Interface for DirectX9
!*********************************************************************
module windx
   use ISO_C_BINDING

   integer, parameter :: D3D_SDK_VERSION        =  32
   integer, parameter :: D3DADAPTER_DEFAULT     =   0
   integer, parameter :: D3DDEVTYPE_HAL         =   1
   integer, parameter :: D3DCREATE_SOFTWARE_VERTEXPROCESSING = INT(Z'0020')
   integer, parameter :: D3DCREATE_HARDWARE_VERTEXPROCESSING = INT(Z'0040')
   integer, parameter :: D3DCREATE_MIXED_VERTEXPROCESSING    = INT(Z'0080')

   integer, parameter :: D3DMULTISAMPLE_NONE    =   0

   integer, parameter :: D3DFMT_UNKNOWN         =   0
   integer, parameter :: D3DFMT_D16             =  80

   integer, parameter :: D3DSWAPEFFECT_DISCARD  =   1

   integer, parameter :: D3DCLEAR_TARGET        =   1
   integer, parameter :: D3DCLEAR_ZBUFFER       =   2
   integer, parameter :: D3DCLEAR_STENCIL       =   4
   integer, parameter :: D3DRS_ZENABLE          =   7
   integer, parameter :: D3DRS_CULLMODE         =  22
   integer, parameter :: D3DRS_ZFUNC            =  23
   integer, parameter :: D3DRS_ALPHABLENDENABLE =  27
   integer, parameter :: D3DRS_AMBIENT          = 139

   integer, parameter :: D3DZB_TRUE             =   1
   integer, parameter :: DDSCL_NORMAL   = Z'00000008'
   integer, parameter :: DDSD_CAPS              =   1
   integer, parameter :: DDSCAPS_PRIMARYSURFACE = 512
   integer, parameter :: D3DCULL_CCW            =   3

   integer, parameter :: D3DFVF_XYZ             = INT(Z'0002')
   integer, parameter :: D3DFVF_XYZRHW          = INT(Z'0004')
   integer, parameter :: D3DFVF_DIFFUSE         = INT(Z'0040')
   integer, parameter :: D3DFVF_NORMAL          = INT(Z'0010')
   integer, parameter :: D3DFVF_VERTEX          = INT(Z'0112')
   integer, parameter :: D3DPT_LINELIST         = 2
   integer, parameter :: D3DPT_LINESTRIP        = 3
   integer, parameter :: D3DPT_TRIANGLELIST     = 4
   integer, parameter :: D3DPT_TRIANGLESTRIP    = 5

   integer, parameter :: D3DTS_VIEW             = 2
   integer, parameter :: D3DTS_PROJECTION       = 3

   type, bind(C) :: D3DPRESENT_PARAMETERS
    integer*4 ::  BackBufferWidth
    integer*4 ::  BackBufferHeight
    integer*4 ::  BackBufferFormat       ! D3DFORMAT
    integer*4 ::  BackBufferCount
    integer*4 ::  MultiSampleType        ! D3DMULTISAMPLE_TYPE
    integer*4 ::  MultiSampleQuality
    integer*4 ::  SwapEffect             ! D3DSWAPEFFECT
    integer(C_INTPTR_T) ::  hDeviceWindow
    logical ::    Windowed
    logical ::    EnableAutoDepthStencil
    integer*4 ::  AutoDepthStencilFormat ! D3DFORMAT
    integer*4 ::  Flags
    integer*4 ::  FullScreen_RefreshRateInHz
    integer*4 ::  PresentationInterval
   end type D3DPRESENT_PARAMETERS

   type, bind(C) :: D3DVIEWPORT9
     integer*4 :: X,Y,Width,Height
     real*4 :: MinZ,MaxZ
   end type D3DVIEWPORT9

   type, bind(C) :: VERTEX
     real*4 :: px,py,pz,rhw
     integer*4 :: icolor
   end type VERTEX

   type, bind(C) :: D3DVECTOR
     real*4 :: x,y,z
   end type D3DVECTOR

   type, bind(C) :: D3DVERTEX
     type (D3DVECTOR) :: p,n  ! p:vertex homogeneous n:vertex normal
     real*4 :: tu,tv          ! tu,tv:vertex texture
   end type D3DVERTEX

   type D3DCOLORVALUE
        real*4 :: r,g,b,a
   end type D3DCOLORVALUE

end module windx

!*********************************************************************
!  Global variable definition 
!*********************************************************************
module WINCOM
   use win32_types
   use windx
   use ISO_C_BINDING

   integer(C_INTPTR_T) lpD3D    ! Direct3D Object Pointer
   integer(C_INTPTR_T) lpD3Ddev ! Pointer to IDirect3DDevice9 component
   type(RECT_T) grect
   type(D3DVECTOR)   gEyePt,axis(6)
   type(D3DVERTEX)   vTr(3,4),vTs(3,4),flr(4)

end module

! *******************************************************************
!     WinMain Function
! *******************************************************************
   integer function WinMain(hInstance, hPrevInstance, lpCmdLine, &
                          nCmdShow) bind(C,name='WinMain')
   use win32_types
   use win32
   use WINCOM
   use ISO_C_BINDING
!GCC$ ATTRIBUTES STDCALL :: WinMain
   external MainWndProc
   integer(C_INTPTR_T), value :: hInstance,hPrevInstance
   integer(C_INT), value :: nCmdShow
   type(C_PTR), value :: lpCmdLine
   integer(C_INTPTR_T) hWnd
   character(kind=C_CHAR), target :: szAppName*(80)
   type (WNDCLASSEX_T) wc
   type (MSG_T) mesg
!
   szAppName = "Dx02"//char(0)
!
   wc%cbSize       = SIZEOF(wc)
   wc%style        = IOR(CS_VREDRAW, CS_HREDRAW)
   wc%lpfnWndProc  = C_FUNLOC(MainWndProc)
   wc%cbClsExtra   = 0
   wc%cbWndExtra   = 0
   wc%hInstance    = hInstance
   wc%hIcon        = LoadIcon(0_C_INTPTR_T, IDI_APPLICATION)
   wc%hCursor      = LoadCursor(0_C_INTPTR_T, IDC_ARROW)
!  wc%hbrBackground= GetStockObject(BLACK_BRUSH)
   wc%hbrBackground= 0
   wc%lpszMenuName = C_NULL_PTR
   wc%lpszClassName= C_LOC(szAppName)
   wc%hIconSm      = LoadIcon(0_C_INTPTR_T, IDI_APPLICATION)
   i = RegisterClassEx(wc)
!
   hWnd = CreateWindowEx(0, szAppName, szAppName, &
           WS_OVERLAPPEDWINDOW,      &
           50,100,                   & ! x,y
           600, 400,                 & ! Width,Height
           0_C_INTPTR_T,             & ! hWndParent
           0_C_INTPTR_T,             & ! hMenu
           hInstance,                & ! hInstance
           C_NULL_PTR)                 ! lpParam
   i = ShowWindow(hWnd, SW_SHOWNORMAL)
   if (i .ne. 0) then
     i = MessageBox(hWnd,'Dx02 failed.'//char(0),'Dx02'//char(0),0)
   end if

   call InitDirect3D(hWnd)
   call DrawFig(hWnd)

   i = UpdateWindow(hWnd)
   do while (GetMessage(mesg,0_C_INTPTR_T,0,0) .NE. 0)
       i = TranslateMessage(mesg)
       i = DispatchMessage(mesg)
   end do
   WinMain = mesg%wParam
   return
   end

!*********************************************************************
!    MainWndProc
!*********************************************************************
   integer function MainWndProc(hWnd,mesg,wParam,lParam) bind(C)
   use win32_types
   use win32
   use WINCOM
   use ISO_C_BINDING
!GCC$ ATTRIBUTES STDCALL :: MainWndProc
   integer(C_INTPTR_T), value :: hWnd,wParam,lParam
   integer(C_INT), value :: mesg
   integer(C_INTPTR_T), save  :: hDC
   type(PAINTSTRUCT_T) ps
   type(RECT_T) rect
   type(POINT_T) pt
   character(kind=C_CHAR) msg*(80)
!
   select case (mesg)
   case (WM_CREATE)
     i = GetClientRect(hWnd,grect)
   case (WM_CLOSE)
     call ClsDirectX
     i = DestroyWindow(hWnd)
   case (WM_DESTROY)
     call PostQuitMessage(0)
   case (WM_PAINT)
     call DrawFig2(hWnd)
   case (WM_KEYDOWN)
     key = IAND(wParam,Z'0000FFFF')
     ish = 0
     if (key == VK_RIGHT) ish = 1
     if (key == VK_LEFT)  ish = 2
     if (key == VK_UP)    ish = 3
     if (key == VK_DOWN)  ish = 4
     call Disp1(ish)
     call DrawFig(hWnd)
   end select
   MainWndProc = DefWindowProc(hWnd, mesg, wParam, lParam)
   return
 end function MainWndProc

!*********************************************************************
!    InitDirect3D
!*********************************************************************
subroutine InitDirect3D(hWnd)
   use win32_types
   use win32
   use windx
   use WINCOM
   use ISO_C_BINDING
!
   integer(C_INTPTR_T) :: hWnd
!
   type(D3DPRESENT_PARAMETERS) :: d3dpp
   type (D3DVIEWPORT9) vp

!== Get Direct3D9 Component
    call XDirect3DCreate9(lpD3D,D3D_SDK_VERSION,iRes)
    if (iRes /= 0) then
     write(6,*)'XDirect3DCreate9',iRes
     return
    end if
!== Create Device
    d3dpp%BackBufferWidth    = 600
    d3dpp%BackBufferHeight   = 400
    d3dpp%BackBufferFormat   = D3DFMT_UNKNOWN
    d3dpp%BackBufferCount    = 1
    d3dpp%MultiSampleType    = D3DMULTISAMPLE_NONE
    d3dpp%MultiSampleQuality = 0
    d3dpp%SwapEffect         = D3DSWAPEFFECT_DISCARD
    d3dpp%hDeviceWindow      = 0_C_INTPTR_T
    d3dpp%Windowed           = .TRUE.
    d3dpp%EnableAutoDepthStencil = .TRUE.
    d3dpp%AutoDepthStencilFormat = D3DFMT_D16
    d3dpp%Flags              = 1
    d3dpp%FullScreen_RefreshRateInHz = 0
    d3dpp%PresentationInterval = 0

    call XCreateDevice &
        (lpD3D,0,1,hWnd,INT(Z'0040'),LOC(d3dpp),LOC(lpD3Ddev),iRes)
    if (iRes /= 0) then
      write(6,*)'XCreateDevice',iRes
      return
    end if
!== Define Pyramid data
    call CreateData
!== Set eye point
    gEyePt = D3DVECTOR(3.0,0.2,-6.0)
    call TransForm(gEyePt)
!== Set light
    call SetLight(0, 0.2,2.5,-2.0,D3DCOLORVALUE(1.0,1.0,1.0,0.0))
    return
    end
!
!*********************************************************************
!    DrawFig
!*********************************************************************
subroutine DrawFig(hWnd)
   use windx
   use WINCOM
   use ISO_C_BINDING
   integer(C_INTPTR_T) :: hWnd

   type (VERTEX)  fr(5)

   call XClear(lpD3Ddev,0,0_C_INTPTR_T,3,INT(Z'00205060'),1.0,0,iRes)

!  Start Draw
   call XBeginScene(lpD3Ddev,iRes)

!  frame
   fr(1)=VERTEX( 20.0, 30.0,1.0,1.0,INT(Z'00ff0000'))
   fr(2)=VERTEX( 20.0,370.0,1.0,1.0,INT(Z'00ff0000'))
   fr(3)=VERTEX(570.0,370.0,1.0,1.0,INT(Z'00ff0000'))
   fr(4)=VERTEX(570.0, 30.0,1.0,1.0,INT(Z'00ff0000'))
   fr(5)=VERTEX( 20.0, 30.0,1.0,1.0,INT(Z'00ff0000'))
   call XSetFVF(lpD3Ddev,68,iRes)     ! D3DFV_XYZRHW|DEFUSE
   call XDrawPrimitiveUP(lpD3Ddev,3,4,LOC(fr),INT(sizeof(fr(1))),iRes)

!  Squre pyramid No.1
   L = sizeof(vTr(1,1))
   call XSetFVF(lpD3Ddev,18,iRes)    ! D3DFVF_XYZ|NORM
   call Material(0.8,0.0,0.0)        ! R,G,B
   do i = 1,4
    call XDrawPrimitiveUP(lpD3Ddev,5,1,LOC(vTr(1,i)),L,iRes)
   end do
!  Squre pyramid No.2
   call Material(0.8,0.9,0.0)        ! R,G,B
   do i = 1,4
    call XDrawPrimitiveUP(lpD3Ddev,5,1,LOC(vTs(1,i)),L,iRes)
   end do
!  Floor
   call Material(1.0,1.0,1.0)
   call XDrawPrimitiveUP(lpD3Ddev,5,2,LOC(flr),L,iRes)
!  Axis
   call XSetFVF(lpD3Ddev,2,iRes)     ! D3DFVF_XYZ
   call Material(0.0,0.0,0.0)        ! R,G,B
   L = sizeof(axis(1))
   call XDrawPrimitiveUP(lpD3Ddev,3,4,LOC(axis(1)),L,iRes)

!  End Draw
   call XEndScene(lpD3Ddev,iRes)
!=====================================================================
!  Show BackBuffer to Display
!=====================================================================
entry DrawFig2(hWnd)
   call XPresent(lpD3Ddev,0_C_INTPTR_T,0_C_INTPTR_T,hWnd,0_C_INTPTR_T, &
        iRes)
   return
   end
!*********************************************************************
!    ClsDirectDraw
!*********************************************************************
subroutine ClsDirectX
   use WINCOM
!== Release all objects
   call XRelease(lpD3Ddev,iRes)
   call XRelease(lpD3D,iRes)
   return
   end

!*********************************************************************
!    CreateDta Subroutine
!     Sets up the vertices for a pyramid.
!*********************************************************************
subroutine CreateData
   use windx
   use WINCOM
   type (D3DVECTOR) v1,v2,v3,v4,n0

! === define axis
    axis(1) = D3DVECTOR(2.5,0.0,0.0)
    axis(2) = D3DVECTOR(0.0,0.0,0.0)
    axis(3) = D3DVECTOR(0.0,2.5,0.0)
    axis(4) = D3DVECTOR(0.0,0.0,0.0)
    axis(5) = D3DVECTOR(0.0,0.0,2.5)

! === 未トランスフォーム&未ライティング頂点(法線ベクトルを含む)を定義する
!   square pyramid No.1
!   1st triangle
    v1 = D3DVECTOR( 0.0, 1.5, 0.0)
    v2 = D3DVECTOR( 1.0,-1.0,-1.0)
    v3 = D3DVECTOR(-1.0,-1.0,-1.0)
    call Norm(v1,v2,v3,n0)
    vTr(1,1) = D3DVERTEX(v1,n0, 0.0,0.0)
    vTr(2,1) = D3DVERTEX(v2,n0, 0.0,0.0)
    vTr(3,1) = D3DVERTEX(v3,n0, 0.0,0.0)
!   2nd triangle
    v1 = D3DVECTOR( 0.0, 1.5, 0.0)
    v2 = D3DVECTOR( 1.0,-1.0, 1.0)
    v3 = D3DVECTOR( 1.0,-1.0,-1.0)
    call Norm(v1,v2,v3,n0)
    vTr(1,2) = D3DVERTEX(v1,n0, 0.0,0.0)
    vTr(2,2) = D3DVERTEX(v2,n0, 0.0,0.0)
    vTr(3,2) = D3DVERTEX(v3,n0, 0.0,0.0)
!   3rd triangle
    v1 = D3DVECTOR( 0.0, 1.5, 0.0)
    v2 = D3DVECTOR(-1.0,-1.0, 1.0)
    v3 = D3DVECTOR( 1.0,-1.0, 1.0)
    call Norm(v1,v2,v3,n0)
    vTr(1,3) = D3DVERTEX(v1,n0, 0.0,0.0)
    vTr(2,3) = D3DVERTEX(v2,n0, 0.0,0.0)
    vTr(3,3) = D3DVERTEX(v3,n0, 0.0,0.0)
!   4th triangle
    v1 = D3DVECTOR( 0.0, 1.5, 0.0)
    v2 = D3DVECTOR(-1.0,-1.0,-1.0)
    v3 = D3DVECTOR(-1.0,-1.0, 1.0)
    call Norm(v1,v2,v3,n0)
    vTr(1,4) = D3DVERTEX(v1,n0, 0.0,0.0)
    vTr(2,4) = D3DVERTEX(v2,n0, 0.0,0.0)
    vTr(3,4) = D3DVERTEX(v3,n0, 0.0,0.0)

!   square pyramid No.2
!   1st triangle
    v1 = D3DVECTOR( 0.0, 1.3, 1.8)
    v2 = D3DVECTOR( 0.8,-1.0, 1.0)
    v3 = D3DVECTOR(-0.8,-1.0, 1.0)
    call Norm(v1,v2,v3,n0)
    vTs(1,1) = D3DVERTEX(v1,n0, 0.0,0.0)
    vTs(2,1) = D3DVERTEX(v2,n0, 0.0,0.0)
    vTs(3,1) = D3DVERTEX(v3,n0, 0.0,0.0)
!   2nd triangle
    v1 = D3DVECTOR( 0.0, 1.3, 1.8)
    v2 = D3DVECTOR( 0.8,-1.0, 2.6)
    v3 = D3DVECTOR( 0.8,-1.0, 1.0)
    call Norm(v1,v2,v3,n0)
    vTs(1,2) = D3DVERTEX(v1,n0, 0.0,0.0)
    vTs(2,2) = D3DVERTEX(v2,n0, 0.0,0.0)
    vTs(3,2) = D3DVERTEX(v3,n0, 0.0,0.0)
!   3rd triangle
    v1 = D3DVECTOR( 0.0, 1.3, 1.8)
    v2 = D3DVECTOR(-0.8,-1.0, 2.6)
    v3 = D3DVECTOR( 0.8,-1.0, 2.6)
    call Norm(v1,v2,v3,n0)
    vTs(1,3) = D3DVERTEX(v1,n0, 0.0,0.0)
    vTs(2,3) = D3DVERTEX(v2,n0, 0.0,0.0)
    vTs(3,3) = D3DVERTEX(v3,n0, 0.0,0.0)
!   4th triangle
    v1 = D3DVECTOR( 0.0, 1.3, 1.8)
    v2 = D3DVECTOR(-0.8,-1.0, 1.0)
    v3 = D3DVECTOR(-0.8,-1.0, 2.6)
    call Norm(v1,v2,v3,n0)
    vTs(1,4) = D3DVERTEX(v1,n0, 0.0,0.0)
    vTs(2,4) = D3DVERTEX(v2,n0, 0.0,0.0)
    vTs(3,4) = D3DVERTEX(v3,n0, 0.0,0.0)

!   Floor
    v1 = D3DVECTOR(-1.5,-1.0, 3.0)
    v2 = D3DVECTOR( 1.5,-1.0, 3.0)
    v3 = D3DVECTOR(-1.5,-1.0,-1.5)
    v4 = D3DVECTOR( 1.5,-1.0,-1.5)
    call Norm(v1,v2,v3,n0)
    flr(1) = D3DVERTEX(v1,n0, 0.0,0.0)
    flr(2) = D3DVERTEX(v2,n0, 0.0,0.0)
    flr(3) = D3DVERTEX(v3,n0, 0.0,0.0)
    flr(4) = D3DVERTEX(v4,n0, 0.0,0.0)
    return
   end

!*********************************************************************
!    SetLight Subroutine
!*********************************************************************
Subroutine SetLight(index,x,y,z,color)
   use win32
   use windx
   use WINCOM

   type (D3DCOLORVALUE) color

   type D3DLIGHT9
     integer*4 :: Type                ! Type of light source
     type (D3DCOLORVALUE) :: diffuse  ! Diffuse color of light
     type (D3DCOLORVALUE) :: specular ! Specular color of light
     type (D3DCOLORVALUE) :: ambient  ! Ambient color of light
     type (D3DVECTOR) :: position     ! Position in world space
     type (D3DVECTOR) :: direction    ! Direction in world space
     real*4 :: range                  ! Cutoff range
     real*4 :: falloff                ! Falloff
     real*4 :: attenuation0           ! Constant attenuation
     real*4 :: attenuation1           ! Linear attenuation
     real*4 :: attenuation2           ! Quadratic attenuation
     real*4 :: theta                  ! Inner angle of spotlight cone
     real*4 :: phi                    ! Outer angle of spotlight cone
   end type D3DLIGHT9

   type (D3DLIGHT9) light

   integer, parameter :: D3DLIGHT_POINT          = 1      ! 点光源
   integer, parameter :: D3DLIGHT_SPOT           = 2      ! スポットライト
   integer, parameter :: D3DLIGHT_DIRECTIONAL    = 3      ! 無限遠光源
   real*4, parameter  :: D3DLIGHT_RANGE_MAX      = 1.0e10
   integer, parameter :: D3DRENDERSTATE_LIGHTING = 137

   call ZeroMemory(LOC(light),SIZEOF(light))
   light%Type         = D3DLIGHT_DIRECTIONAL ! 光源タイプ
   light%diffuse      = color                ! 光源が放出するディフューズ色
   light%specular     = color                ! 光源が放出するスペキュラ色
   light%ambient%r    = color%r*0.3          ! 自然光
   light%ambient%g    = color%g*0.3
   light%ambient%b    = color%b*0.3
   light%ambient%a    = color%a*0.3
   light%direction%x  = x                    ! ワールド空間で光が指す方向
   light%direction%y  = y
   light%direction%z  = z
   light%position%x   = x                    ! ワールド空間での光源の位置座標
   light%position%y   = y
   light%position%z   = z
   light%attenuation0 = 1.0                  ! 光の減衰定数
   light%range        = D3DLIGHT_RANGE_MAX   ! 光源の有効距離

   call XSetLight(lpD3Ddev,index,LOC(light),iRes)

   call XLightEnable(lpD3Ddev,index,.TRUE.,iRes)

   return
   end

!*********************************************************************
!    Material Subroutine
!*********************************************************************
   subroutine Material(red,green,blue)
   use win32
   use windx
   use WINCOM

   type D3DMATERIAL9
     type (D3DCOLORVALUE) :: diffuse    ! ディフーズ色
     type (D3DCOLORVALUE) :: ambient    ! アンビエント色
     type (D3DCOLORVALUE) :: specular   ! スペキュラ色
     type (D3DCOLORVALUE) :: emissive   ! エミッション色
     real*4 :: power                    ! スペキュラハイライトの鮮明度
   end type D3DMATERIAL9

   type (D3DMATERIAL9) mtrl

   call ZeroMemory(LOC(mtrl),SIZEOF(mtrl))
   mtrl%diffuse%r = red
   mtrl%diffuse%g = green
   mtrl%diffuse%b = blue
   mtrl%diffuse%a = 0.0
   mtrl%ambient%r = red * 0.3
   mtrl%ambient%g = green * 0.3
   mtrl%ambient%b = blue * 0.3
   mtrl%ambient%a = 0.0
   mtrl%power = 10.0

   call XSetMaterial(lpD3Ddev,LOC(mtrl),iRes)
   return
   end

!*********************************************************************
!    Disp1 Subroutine
!    視点位置を回転する
!*********************************************************************
   subroutine Disp1(ISH)
   use WINCOM

   CO=COS(0.08727)   ! PI / 36.0 = 0.087266
   SI=SIN(0.08727)   ! 回転角を5°に設定
   XF = gEyePt%x
   YF = gEyePt%y
   ZF = gEyePt%z
   select case (ISH)
   case (1)    ! 視点がY軸中心に右回転
     CALL ROTATY(XF,ZF,0.0,0.0,CO, SI)
   case (2)    ! 視点がY軸中心に左回転
     CALL ROTATY(XF,ZF,0.0,0.0,CO,-SI)
   case (3)    ! 視点が上方向に回転
     CALL ROTATV(XF,YF,ZF,0.0,0.0,0.0,CO,-SI)
   case (4)    ! 視点が下方向に回転
     CALL ROTATV(XF,YF,ZF,0.0,0.0,0.0,CO, SI)
   end select
   gEyePt%x = XF
   gEyePt%y = YF
   gEyePt%z = ZF
   call TransForm(gEyePt)
   return
   end

!*********************************************************************
!   ROTATE SUBROUTINE.
!*********************************************************************
!  X軸周りに回転
Subroutine ROTATX(Y,Z,Y0,Z0,CO,SI)
   YW=Y-Y0
   ZW=Z-Z0
   Y=YW*CO+ZW*SI+Y0
   Z=ZW*CO-YW*SI+Z0
   RETURN
!  Y軸周りに回転
Entry ROTATY(X,Z,X0,Z0,CO,SI)
   XW=X-X0
   ZW=Z-Z0
   X=XW*CO-ZW*SI+X0
   Z=XW*SI+ZW*CO+Z0
   RETURN
!  Z軸回りに回転
ENTRY ROTATZ(X,Y,X0,Y0,CO,SI)
   XW=X-X0
   YW=Y-Y0
   X=XW*CO+YW*SI+X0
   Y=YW*CO-XW*SI+Y0
   RETURN
!  垂直方向に回転
ENTRY ROTATV(X,Y,Z,X0,Y0,Z0,CO,SI)
   XW = X - X0
   YW = Y - Y0
   ZW = Z - Z0
   R  = SQRT(XW**2+ZW**2)
   if (R < 1.0E-5) return
   RI = -1.0 / R
   C  = RI * ZW
   S  = RI * XW
   Z1 = XW * S  + ZW * C
   X2 = XW * C  - ZW * S
   Z2 = Z1 * CO - YW * SI
   X  = X2 * C  + Z2 * S  + X0
   Y  = YW * CO + Z1 * SI + Y0
   Z  = Z2 * C  - X2 * S  + Z0
   RETURN
!  任意直線回りに回転
ENTRY ROTATS(X,Y,Z,U,V,W,CO,SI)
   XW = X
   YW = Y
   ZW = Z
   CI = 1.0-CO
   UCI= U*CI
   VCI= V*CI
   WCI= W*CI
   US = U*SI
   VS = V*SI
   WS = W*SI
   X  = (U*UCI+CO)*XW+(U*VCI+WS)*YW+(U*WCI-VS)*ZW
   Y  = (V*UCI-WS)*XW+(V*VCI+CO)*YW+(V*WCI+US)*ZW
   Z  = (W*UCI+VS)*XW+(W*VCI-US)*YW+(W*WCI+CO)*ZW
   RETURN
end

!*********************************************************************
!    TransForm Subroutine
!    トランスフォームマトリックスを作成しDirectXに設定
!*********************************************************************
Subroutine TransForm(vEyePt)
   use windx
   use WINCOM
   type (D3DVECTOR) vLookatPt,vUpVec,vEyePt
   real*4, parameter  :: PI = 3.1415926
   real*4 matView(4,4),matProj(4,4)

!  ビュー変換マトリックスの設定(ビューポイントの定義)
   vLookatPt = D3DVECTOR(0.0, 0.0, 0.0) ! 注視点
   vUpVec    = D3DVECTOR(0.0, 1.0, 0.0) ! 上方向単位ベクトル
   i = iSetViewMatrix(matView, vEyePt, vLookatPt, vUpVec)

!             |  Ux   Vx   Nx   0  |   U:右方向ベクトル
!   matView = |  Uy   Vy   Ny   0  |   V:上方向ベクトル
!             |  Uz   Vz   Nz   0  |   N:ビュー方向ベクトル
!             | -U*C -V*C -N*C  1  |   C:視点の位置座標

   call XSetTransform(lpD3Ddev,D3DTS_VIEW,matView,icon)

!   プロジェクション変換マトリックスの設定
   Fov    = PI*0.25   ! 視野角45°(ラジアン)
   Aspect = 0.75      ! アスペクト比(画面の縦横比4:3)
   Znear  = 1.0       ! 前方クリップ面までの距離
   Zfar   = 100.0     ! 後方クリップ面までの距離
   i = iSetProjectionMatrix(matProj,Fov,Aspect,Znear,Zfar)

!             | w  0   0  0|
!   matProj = | 0  h   0  0|
!             | 0  0   Q  1|
!             | 0  0 -QZn 0|

   call XSetTransform(lpD3Ddev,D3DTS_PROJECTION,matProj,icon)
   return
end

!*********************************************************************
!   SetViewMatrix Function   <== d3dutil.cpp
!   視点位置座標と注視点に基づいてビュー行列を作成する
!     Given an eye point, a lookat point, and an up vector, this
!     function builds a 4x4 view matrix.
!*********************************************************************
integer function iSetViewMatrix(mat,vFrom,vAt,vWorldUp)
   use WINCOM
   type (D3DVECTOR) vFrom,vAt,vWorldUp,vView,vUp,vRight,v1,v2
   real*4 mat(4,4)
!   関数定義
    DotProduct(v1,v2) = v1%x*v2%x + v1%y*v2%y + v1%z*v2%z  ! 内積の計算

!   注視点から視点位置座標を減算して,視線の方向ベクトルn(vView)を生成する。
!   Get the z basis vector, which points straight ahead. 
    vView%x = vAt%x - vFrom%x
    vView%y = vAt%y - vFrom%y
    vView%z = vAt%z - vFrom%z
!   視線の方向ベクトル長が 0 の場合はエラー
    fLength2 = vView%x**2 + vView%y**2 + vView%z**2
    if( fLength2 < 1.0E-6 ) then
      SetViewMatrix = -1
      return
    end if
!   視線の方向ベクトル(z軸の基底ベクトル)を正規化する。
!   Normalize the z basis vector.
    af = 1.0 / SQRT(fLength2)
    vView%x = vView%x * af
    vView%y = vView%y * af
    vView%z = vView%z * af
!
!   ベクトルnとワールド空間のy軸の内積を取得して,上方向ベクトルに対するZ軸の
!   基底ベクトルの射影を計算する。 この射影は y 軸の基底ベクトルである。
!   Get the dot product, and calculate the projection of the z basis vector
!   onto the up vector.  The projection is the y basis vector.
    fDotProduct = DotProduct(vWorldUp, vView)
    vUp%x = vWorldUp%x - fDotProduct * vView%x
    vUp%y = vWorldUp%y - fDotProduct * vView%y
    vUp%z = vWorldUp%z - fDotProduct * vView%z
!
!   不正な上方向ベクトルを入力したためにベクトル長がゼロに近くなった場合は,
!   上方向ベクトルをデフォルト値にする。(Y軸上に視点がある場合)
!   If this vector has near-zero length because the input specified a
!   bogus up vector, let's try a default up vector
    fLength2 = vUp%x**2 + vUp%y**2 + vUp%z**2
    if( fLength2 < 1.0E-6 ) then
      vUp%x = - vView%y * vView%x
      vUp%y = 1.0 - vView%y * vView%y
      vUp%z = - vView%y * vView%z
!     ベクトルがなおゼロに近ければ,別の軸を利用する。
!     If we still have near-zero length, resort to a different axis.
      fLength2 = vUp%x**2 + vUp%y**2 + vUp%z**2
      if( fLength2 < 1.0E-6 ) then
        vUp%x = - vView%z * vView%x
        vUp%y = - vView%z * vView%y
        vUp%z = 1.0 - vView%z * vView%z
        fLength2 = vUp%x**2 + vUp%y**2 + vUp%z**2
        if( fLength2 < 1.0E-6 ) then
          SetViewMatrix = -1   ! error return
          return
        end if
      end if
    end if
!   y 軸の基底ベクトルを正規化する。
!   Normalize the y basis vector.
    w = 1.0 / SQRT(fLength2)
    vUp%x = vUp%x * w
    vUp%y = vUp%y * w
    vUp%z = vUp%z * w
!
!   y軸及びz軸の基底ベクトルの外積をとり,x軸の基底ベクトルを求める。
!   The x basis vector is found simply with the cross product of the y
!   and z basis vectors.
    vRight%x = vUp%y * vView%z - vUp%z * vView%y
    vRight%y = vUp%z * vView%x - vUp%x * vView%z
    vRight%z = vUp%x * vView%y - vUp%y * vView%x
!
!   ビュー行列を生成する(回転と移動を扱うため4×4の行列を用いる)。
!   左上の 3×3 行には,ビューを注視点で回転するための基底ベクトルを格納する。
!   4行目には移動値を格納する (回転はまだ視点にある)。
!   Building the view matrix. The first three rows contains the basis vectors
!   used to rotate the view to point at the look at point.
!   Do the translation values (rotations are still about the eyepoint)
!   (注) C/C++とFortranでは,行と列が逆のため C/C++ に合わせる。
    mat(1,1) = vRight%x
    mat(1,2) = vRight%y   !  |  Ux   Vx   Nx   0  |  U:右方向ベクトル
    mat(1,3) = vRight%z   !  |                    |  V:上方向ベクトル
    mat(2,1) = vUp%x      !  |  Uy   Vy   Ny   0  |  N:ビュー方向ベクトル
    mat(2,2) = vUp%y      !  |                    |  C:カメラの位置座標
    mat(2,3) = vUp%z      !  |  Uz   Vz   Nz   0  |
    mat(3,1) = vView%x    !  |                    |
    mat(3,2) = vView%y    !  | -U*C -V*C -N*C  1  |
    mat(3,3) = vView%z
    mat(4,1) = 0.0
    mat(4,2) = 0.0
    mat(4,3) = 0.0
    mat(1,4) = - DotProduct(vFrom, vRight)  ! 平行移動値の設定
    mat(2,4) = - DotProduct(vFrom, vUp)     ! (DotProduct:内積)
    mat(3,4) = - DotProduct(vFrom, vView)   !
    mat(4,4) = 1.0

    iSetViewMatrix = 0
    return
   end

!*********************************************************************
!   SetProjectionMatrix Function    透視変換行列を設定
!     Fov      : 視野角
!     Aspect   : アスペクト比(縦横比)
!     Znear    : 前方クリップ面(投影面)までの距離
!     Zfar     : 後方クリップ面(遠方面)までの距離
!*********************************************************************
integer function iSetProjectionMatrix(mat,Fov,Aspect,Znear,Zfar)
   real*4 mat(4,4)
    if(ABS(zFar-zNear) < 0.01 .or. ABS(SIN(Fov*0.5)) < 0.01) then
      SetProjectionMatrix = -1
      return
    end if
!         | w  0   0  0|  w = Cot(fovw/2)=2*Zn/Vw  fovw:水平方向視野(ラジアン)
!   mat = | 0  h   0  0|  h = Cot(fovh/2)=2*Zn/Vh  fowh:垂直方向視野(ラジアン)
!         | 0  0   Q  1|  Q = Zf/(Zf-Zn)           Vw:ビューポートの幅
!         | 0  0 -QZn 0|                           Vh:ビューポートの高さ

    h = 1.0 / TAN(Fov*0.5)
    Q = Zfar / (Zfar - Znear)
!   (注) C/C++とFortranでは,行と列が逆のため C/C++ に合わせる。
    mat = 0.0
    mat(1,1) = Aspect * h
    mat(2,2) = h
    mat(3,3) = Q
    mat(4,3) = 1.0
    mat(3,4)= - Q * Znear
    iSetProjectionMatrix = 0
    return
   end
!*********************************************************************
!   Norm Subroutine    法線ベクトルの計算
!*********************************************************************
Subroutine Norm(v1,v2,v3,vn)
   use windx
   type (D3DVECTOR) v1,v2,v3,vn
   p = (v1%z-v3%z) * (v2%y-v1%y) - (v1%y-v3%y) * (v2%z-v1%z)
   q = (v1%x-v3%x) * (v2%z-v1%z) - (v1%z-v3%z) * (v2%x-v1%x)
   r = (v1%y-v3%y) * (v2%x-v1%x) - (v1%x-v3%x) * (v2%y-v1%y)
   w = 1.0 / SQRT(p**2 + q**2 + r**2)
   vn%x = p * w
   vn%y = q * w
   vn%z = r * w
   end
!*********************************************************************
!    Direct3D9 interface routine
!*********************************************************************
Subroutine XDirect3DCreate9(lpD3D,SDKVersion,icon)
   use win32_types
   use win32
   use ISO_C_BINDING
   integer(C_INTPTR_T) :: lpD3D,lpD3Ddev
   integer(C_INT) :: SDKVersion,icon

   integer(C_INTPTR_T) :: hWnd,hFWnd,ddsd,lphDC,hDC
   integer(C_INTPTR_T) :: pPreParm,ppRetDev,pdRegion,plight
   integer(C_INTPTR_T) :: srect,drect,prects,lpdata,pVport,pmaterial
   integer(C_INT) :: dwFlags,dpUnkOuter,type,Svtex,count,stride,fvf
   integer(C_INT) :: Adapter,DevType,BFlags,rectc,flags,color,stencil
   integer(C_INT) :: dstate,value,index
   real(C_FLOAT) :: z,matrix(4,4)
   logical(4) :: Enable

   interface

   function Direct3DCreate9(SDKVersion) bind(C,name='Direct3DCreate9')
   use ISO_C_BINDING
!GCC$ ATTRIBUTES STDCALL :: Direct3DCreate9
   integer(C_INTPTR_T) :: Direct3DCreate9
   integer(C_INT), value :: SDKVersion
   end function

   integer function CreateDevice(lpD3D,Adapter,DevType,hFocusWindow, &
           BehavFlags,pPreParam,ppRetDev) bind(C,name='CreateDevice')
   use ISO_C_BINDING
!GCC$ ATTRIBUTES STDCALL :: CreateDevice
   integer(C_INTPTR_T), value :: lpD3D         ! Object Pointer
   integer(C_INT), value :: Adapter,DevType,BehavFlags
   integer(C_INTPTR_T), value :: hFocusWindow,pPreParam,ppRetDev
   end function

   integer function Release(lpD3D) bind(C,name='Release')
   use ISO_C_BINDING
!GCC$ ATTRIBUTES STDCALL :: Release
   integer(C_INTPTR_T), value :: lpD3D
   end function

   integer function BeginScene(lpD3Ddev) bind(C,name='BeginScene')
   use ISO_C_BINDING
!GCC$ ATTRIBUTES STDCALL :: BeginScene
   integer(C_INTPTR_T), value :: lpD3Ddev
   end function

   integer function EndScene(lpD3Ddev) bind(C,name='EndScene')
   use ISO_C_BINDING
!GCC$ ATTRIBUTES STDCALL :: EndScene
   integer(C_INTPTR_T), value :: lpD3Ddev
   end function

   integer function Clear(lpD3Ddev,rectc,prects,flags,color, &
           z,stencil) bind(C,name='Clear')
   use ISO_C_BINDING
!GCC$ ATTRIBUTES STDCALL :: Clear
   integer(C_INTPTR_T), value :: lpD3Ddev
   integer(C_INT), value :: rectc,flags,color,stencil
   integer(C_INTPTR_T), value :: prects
   real(C_FLOAT), value :: z
   end function

   integer function Present(lpD3Ddev,srect,drect,hWnd,pdRegion)  &
           bind(C,name='Present')
   use win32_types
   use ISO_C_BINDING
!GCC$ ATTRIBUTES STDCALL :: Present
   integer(C_INTPTR_T), value :: lpD3Ddev
   integer(C_INTPTR_T), value :: srect,drect,hWnd,pdRegion
   end function

   integer function SetFVF(lpD3Ddev,fvf) bind(C,name='SetFVF')
   use ISO_C_BINDING
!GCC$ ATTRIBUTES STDCALL :: SetFVF
   integer(C_INTPTR_T), value :: lpD3Ddev
   integer(C_INT), value :: fvf
   end function

   integer function DrawPrimitive(lpD3Ddev,type,Svtex,count) &
           bind(C,name='DrawPrimitive')
   use ISO_C_BINDING
!GCC$ ATTRIBUTES STDCALL :: DrawPrimitive
   integer(C_INTPTR_T), value :: lpD3Ddev
   integer(C_INT), value :: type,Svtex,count
   end function

   integer function DrawPrimitiveUP(lpD3Ddev,type,count,lpdata,stride) &
           bind(C,name='DrawPrimitiveUP')
   use ISO_C_BINDING
!GCC$ ATTRIBUTES STDCALL :: DrawPrimitiveUP
   integer(C_INTPTR_T), value :: lpD3Ddev
   integer(C_INT), value :: type,count,stride
   integer(C_INTPTR_T), value :: lpdata
   end function

   integer function SetViewport(lpD3Ddev,pVport) bind(C,name='SetViewport')
   use ISO_C_BINDING
!GCC$ ATTRIBUTES STDCALL :: SetViewport
   integer(C_INTPTR_T), value :: lpD3Ddev
   integer(C_INTPTR_T), value :: pVport
   end function

   integer function SetMaterial(lpD3Ddev,pmaterial) bind(C,name='SetMaterial')
   use ISO_C_BINDING
!GCC$ ATTRIBUTES STDCALL :: SetMaterial
   integer(C_INTPTR_T), value :: lpD3Ddev
   integer(C_INTPTR_T), value :: pmaterial
   end function

   integer function SetLight(lpD3Ddev,index,plight) bind(C,name='SetLight')
   use ISO_C_BINDING
!GCC$ ATTRIBUTES STDCALL :: SetLight
   integer(C_INTPTR_T), value :: lpD3Ddev
   integer(C_INT), value :: index
   integer(C_INTPTR_T), value :: plight
   end function

   integer function LightEnable(lpD3Ddev,index,Enable)  &
           bind(C,name='LightEnable')
   use ISO_C_BINDING
!GCC$ ATTRIBUTES STDCALL :: LightEnable
   integer(C_INTPTR_T), value :: lpD3Ddev
   integer(C_INT), value :: index
   logical(4), value :: Enable
   end function

   integer function SetRenderState(lpD3Ddev,dstate,value) &
           bind(C,name='SetRenderState')
   use ISO_C_BINDING
!GCC$ ATTRIBUTES STDCALL :: SetRenderState
   integer(C_INTPTR_T), value :: lpD3Ddev
   integer(C_INT), value :: dstate,value
   end function

   integer function SetTransform(lpD3Ddev,transformType,matrix) &
           bind(C,name='SetTransform')
   use ISO_C_BINDING
!GCC$ ATTRIBUTES STDCALL :: SetTransform
   integer(C_INTPTR_T), value :: lpD3Ddev
   integer(C_INT), value :: transformType
   real(C_FLOAT) :: matrix(4,4)
   end function

   end interface

   procedure(CreateDevice),pointer :: ptrSub16
   procedure(Release),pointer :: ptrSub2
   procedure(Present), pointer, save :: ptrSub17 => NULL()
   procedure(BeginScene), pointer, save :: ptrSub41 => NULL()
   procedure(EndScene), pointer, save :: ptrSub42 => NULL()
   procedure(Clear), pointer, save :: ptrSub43 => NULL()
   procedure(SetTransform), pointer, save :: ptrSub44 => NULL()
   procedure(SetViewport), pointer, save :: ptrSub47 => NULL()
   procedure(SetMaterial), pointer, save :: ptrSub49 => NULL()
   procedure(SetLight), pointer, save :: ptrSub51 => NULL()
   procedure(LightEnable), pointer, save :: ptrSub53 => NULL()
   procedure(SetRenderState), pointer, save :: ptrSub57 => NULL()
   procedure(DrawPrimitive), pointer, save :: ptrSub81 => NULL()
   procedure(DrawPrimitiveUP), pointer, save :: ptrSub83 => NULL()
   procedure(SetFVF), pointer, save :: ptrSub89 => NULL()

   integer(C_INTPTR_T), save :: pVPTR,M
   type(C_FUNPTR), save :: cADX

   M = sizeof(M)
   lpD3D = Direct3DCreate9(SDKVersion)
   icon = 1
   if (lpD3D /= 0)icon = 0
   return
!=====================================================================
!    Release interface routine
!=====================================================================
entry XRelease(lpD3D,icon)
   if(lpD3D.eq.0_C_INTPTR_T)then
     icon = 1
     return
   end if
   call MoveMemory(LOC(pVPTR),lpD3D,M)
   pVPTR = pVPTR + M * 2
   call MoveMemory(LOC(cADX),pVPTR,M)
   call C_F_PROCPOINTER(cADX,ptrSub2)
   icon = ptrSub2(lpD3D)
   return
!=====================================================================
!    CreateDevice interface routine
!=====================================================================
entry XCreateDevice(lpD3D,Adapter,DevType,hFWnd,BFlags,pPreParm, &
                    ppRetDev,icon)
   call MoveMemory(LOC(pVPTR),lpD3D,M)
   pVPTR = pVPTR + M * 16
   call MoveMemory(LOC(cADX),pVPTR,M)
   call C_F_PROCPOINTER(cADX,ptrSub16)
   icon = ptrSub16(lpD3D,Adapter,DevType,hFWnd,BFlags,pPreParm,ppRetDev)
   return
!=====================================================================
!    BeginScene method interface   lpD3Ddev:IDirect3DDevice9 interface
!=====================================================================
entry XBeginScene(lpD3Ddev,icon)
   if (.not. associated(ptrSub41)) then
     call MoveMemory(LOC(pVPTR),lpD3Ddev,M)
     pVPTR = pVPTR + M * 41
     call MoveMemory(LOC(cADX),pVPTR,M)
     call C_F_PROCPOINTER(cADX,ptrSub41)
   end if
   icon = ptrSub41(lpD3Ddev)
   return
!=====================================================================
!    EndScene method interface routine
!=====================================================================
entry XEndScene(lpD3Ddev,icon)
   if (.not. associated(ptrSub42)) then
     call MoveMemory(LOC(pVPTR),lpD3Ddev,M)
     pVPTR = pVPTR + M * 42
     call MoveMemory(LOC(cADX),pVPTR,M)
     call C_F_PROCPOINTER(cADX,ptrSub42)
   end if
   icon = ptrSub42(lpD3Ddev)
   return
!=====================================================================
!    Clear method interface routine
!=====================================================================
entry XClear(lpD3Ddev,rectc,prects,flags,color,z,stencil,icon)
   if (.not. associated(ptrSub43)) then
     call MoveMemory(LOC(pVPTR),lpD3Ddev,M)
     pVPTR = pVPTR + M * 43
     call MoveMemory(LOC(cADX),pVPTR,M)
     call C_F_PROCPOINTER(cADX,ptrSub43)
   end if
   icon = ptrSub43(lpD3Ddev,rectc,prects,flags,color,z,stencil)
   return
!=====================================================================
!    Present method interface routine
!=====================================================================
entry XPresent(lpD3Ddev,srect,drect,hWnd,pdRegion,icon)
   if (.not. associated(ptrSub17)) then
     call MoveMemory(LOC(pVPTR),lpD3Ddev,M)
     pVPTR = pVPTR + M * 17
     call MoveMemory(LOC(cADX),pVPTR,M)
     call C_F_PROCPOINTER(cADX,ptrSub17)
   end if
   icon = ptrSub17(lpD3Ddev,srect,drect,hWnd,pdRegion)
   return
!=====================================================================
!    DrawPrimitive method interface routine
!=====================================================================
entry XDrawPrimitive(lpD3Ddev,type,Svtex,count,icon)
   if (.not. associated(ptrSub81)) then
     call MoveMemory(LOC(pVPTR),lpD3Ddev,M)
     pVPTR = pVPTR + M * 81
     call MoveMemory(LOC(cADX),pVPTR,M)
     call C_F_PROCPOINTER(cADX,ptrSub81)
   end if
   icon = ptrSub81(lpD3Ddev,type,Svtex,count)
   return
!=====================================================================
!    DrawPrimitiveUP method interface routine
!=====================================================================
entry XDrawPrimitiveUP(lpD3Ddev,type,count,lpdata,stride,icon)
   if (.not. associated(ptrSub83)) then
     call MoveMemory(LOC(pVPTR),lpD3Ddev,M)
     pVPTR = pVPTR + M * 83
     call MoveMemory(LOC(cADX),pVPTR,M)
     call C_F_PROCPOINTER(cADX,ptrSub83)
   end if
   icon = ptrSub83(lpD3Ddev,type,count,lpdata,stride)
   return
!=====================================================================
!    SetFVF method interface routine
!=====================================================================
entry XSetFVF(lpD3Ddev,fvf,icon)
   if (.not. associated(ptrSub89)) then
     call MoveMemory(LOC(pVPTR),lpD3Ddev,M)
     pVPTR = pVPTR + M * 89
     call MoveMemory(LOC(cADX),pVPTR,M)
     call C_F_PROCPOINTER(cADX,ptrSub89)
   end if
   icon = ptrSub89(lpD3Ddev,fvf)
   return
!=====================================================================
!    SetViewport method interface routine
!=====================================================================
entry XSetViewport(lpD3Ddev,pVport,icon)
   if (.not. associated(ptrSub47)) then
     call MoveMemory(LOC(pVPTR),lpD3Ddev,M)
     pVPTR = pVPTR + M * 47
     call MoveMemory(LOC(cADX),pVPTR,M)
     call C_F_PROCPOINTER(cADX,ptrSub47)
   end if
   icon = ptrSub47(lpD3Ddev,pVport)
   return
!=====================================================================
!    SetMaterial method interface routine
!=====================================================================
entry XSetMaterial(lpD3Ddev,pmaterial,icon)
   if (.not. associated(ptrSub49)) then
     call MoveMemory(LOC(pVPTR),lpD3Ddev,M)
     pVPTR = pVPTR + M * 49
     call MoveMemory(LOC(cADX),pVPTR,M)
     call C_F_PROCPOINTER(cADX,ptrSub49)
   end if
   icon = ptrSub49(lpD3Ddev,pmaterial)
   return
!=====================================================================
!    SetLight method interface routine
!=====================================================================
entry XSetLight(lpD3Ddev,index,plight,icon)
   if (.not. associated(ptrSub51)) then
     call MoveMemory(LOC(pVPTR),lpD3Ddev,M)
     pVPTR = pVPTR + M * 51
     call MoveMemory(LOC(cADX),pVPTR,M)
     call C_F_PROCPOINTER(cADX,ptrSub51)
   end if
   icon = ptrSub51(lpD3Ddev,index,plight)
   return
!=====================================================================
!    LightEnable method interface routine
!=====================================================================
entry XLightEnable(lpD3Ddev,index,Enable,icon)
   if (.not. associated(ptrSub53)) then
     call MoveMemory(LOC(pVPTR),lpD3Ddev,M)
     pVPTR = pVPTR + M * 53
     call MoveMemory(LOC(cADX),pVPTR,M)
     call C_F_PROCPOINTER(cADX,ptrSub53)
   end if
   icon = ptrSub53(lpD3Ddev,index,Enable)
   return
!=====================================================================
!    SetRenderState method interface routine
!=====================================================================
entry XSetRenderState(lpD3Ddev,dstate,value,icon)
   if (.not. associated(ptrSub57)) then
     call MoveMemory(LOC(pVPTR),lpD3Ddev,M)
     pVPTR = pVPTR + M * 57
     call MoveMemory(LOC(cADX),pVPTR,M)
     call C_F_PROCPOINTER(cADX,ptrSub57)
   end if
   icon = ptrSub57(lpD3Ddev,dstate,value)
   return
!=====================================================================
!    SetTranform method interface routine
!=====================================================================
entry XSetTransform(lpD3Ddev,dstate,matrix,icon)
   if (.not. associated(ptrSub44)) then
     call MoveMemory(LOC(pVPTR),lpD3Ddev,M)
     pVPTR = pVPTR + M * 44
     call MoveMemory(LOC(cADX),pVPTR,M)
     call C_F_PROCPOINTER(cADX,ptrSub44)
   end if
   icon = ptrSub44(lpD3Ddev,dstate,matrix)
   return
end